ECS の dependsOn で HEALTHY に依存させて HEALTHY にならなければ無限に待ち続けることがある

provider "aws" {}

locals {
  application_name = "healthy-dependency-example"
}

data "aws_subnet" "default_1a" {
  default_for_az = true

  filter {
    name   = "availability-zone"
    values = ["ap-northeast-1a"]
  }
}

data "aws_ami" "most_recent_ecs_optimized" {
  most_recent = true
  owners      = ["amazon"]

  filter {
    name   = "name"
    values = ["amzn2-ami-ecs-hvm-2.0.*-x86_64-ebs"]
  }
}

resource "aws_ecs_cluster" "main" {
  name = local.application_name
}

resource "aws_ecs_task_definition" "main" {
  family = local.application_name
  # fluetnd never becomes healhty
  container_definitions = <<-JSON
  [
    {
      "name": "main",
      "image": "ubuntu",
      "essential": true,
      "memoryReservation": 50,
      "dependsOn": [
        {
        "containerName": "fluentd",
        "condition": "HEALTHY"
        }
      ]
    },
    {
      "name": "fluentd",
      "image": "fluent/fluentd:v1.14.5-1.1",
      "essential": true,
      "memoryReservation": 50,
      "healthCheck": {
        "command": ["CMD", "nc", "-z", "127.0.0.1", "24225"],
        "interval": 5,
        "timeout": 5,
        "retries": 10
      }
    }
  ]
  JSON
}

resource "aws_ecs_service" "fluentd_forwarder" {
  name            = aws_ecs_task_definition.main.family
  cluster         = aws_ecs_cluster.main.name
  task_definition = aws_ecs_task_definition.main.arn
  desired_count   = 1
}


resource "aws_instance" "main" {
  ami           = data.aws_ami.most_recent_ecs_optimized.image_id
  instance_type = "c5.large"

  subnet_id = data.aws_subnet.default_1a.id

  associate_public_ip_address = true

  iam_instance_profile = "ecsInstanceRole"

  tags = {
    Name = local.application_name
  }

  user_data = <<-DATA
  #!/bin/bash
  cat <<'EOF' >> /etc/ecs/ecs.config
  ECS_CLUSTER=${aws_ecs_cluster.main.name}
  ECS_AVAILABLE_LOGGING_DRIVERS=["awslogs","fluentd"]
  EOF
  DATA
}